以前に抵抗ラダー回路の問題があったが今度はコンデンサーのラダー回路。



最初の図の合成容量Cadを求めるというもの。

コンデンサの直列・並列混在回路なので式を立てると

(%i1) Cad=(C5+1/(1/C4+1/(C3+1/(1/C2+1/C1))));
(%o1) Cad=C5+1/(1/C4+1/(C3+1/(1/C2+1/C1)))
(%i2) factor(%);
(%o2) Cad=(C2*C4*C5+C1*C4*C5+C2*C3*C5+C1*C3*C5+C1*C2*C5+C2*C3*C4+C1*C3*C4+C1*C2*C4)/(C2*C4+C1*C4+C2*C3+C1*C3+C1*C2)

一見すると著者の解とは似てもにつかぬが、

(%i3) ratsimp(%);
(%o3) Cad=(((C2+C1)*C4+(C2+C1)*C3+C1*C2)*C5+((C2+C1)*C3+C1*C2)*C4)/((C2+C1)*C4+(C2+C1)*C3+C1*C2)

とすると分子のC5にかかっている式が分母で割り切れることがわかる。

すなわち

Cad = R5 + ((C2+C1)*C3+C1*C2)*C4/((C2+C1)*C4+(C2+C1)*C3+C1*C2)

ということになり著者の解と同じ式であることがわかる。

同様にラダーが∞に続く場合は、

(%i16) Cinf=C+(1/(1/C+1/Cinf));
(%o16) Cinf=C+1/(1/C+1/Cinf)

Cinfについて解くと

(%i17) solve(%,Cinf);
(%o17) [Cinf=-((sqrt(5)-1)*C)/2,Cinf=((sqrt(5)+1)*C)/2]

ということで著者と同じ答えが得られる。

こんどは予め充電済みのコンデンサを並列につないだときに失われる静電エネルギーを求めるというもの。

これはいろいろ解き方があると思われる。いつものようにひねくれた解き方をやってみる。



まだ並列につないでいない状態の２つのコンデンサはそれぞれ蓄えられた電荷が移動せずに均衡を保っている。

並列に接続するということは合成容量Cのコンデンサに蓄えられていた電荷を一気に短絡させて失わせることを意味する。ということで合成容量Cのコンデンサに蓄えれていた静電エネルギーがコンデンサを並列に接続した際に短絡によって失われると考えることが出来る。

図から方程式を立てると

(%i23) e1: C=(1/(1/C1+1/C2));
(%o23) C=1/(1/C2+1/C1)
(%i24) e2: Q=C*(E2-E1);
(%o24) Q=C*(E2-E1)
(%i32) e3: W=Q*(E2-E1)/2;
(%o32) W=((E2-E1)*Q)/2

これらの方程式からC,Q,Wを解くと

(%i33) solve([e1,e2,e3],[C,Q,W]);
(%o33) [[C=(C1*C2)/(C2+C1),Q=(C1*C2*(E2-E1))/(C2+C1),W=(C1*C2*(E2^2-2*E1*E2+E1^2))/(2*C2+2*C1)]]

因数分解すると

(%i34) factor(%);
(%o34) [[C=(C1*C2)/(C2+C1),Q=(C1*C2*(E2-E1))/(C2+C1),W=(C1*C2*(E2-E1)^2)/(2*(C2+C1))]]

E2とE1の差分の式が著者と逆だが２乗するので負号は関係なく結果は一緒になる。

よく考えると問題では接続の向きについては何も書いていない。もし充電された極性が逆向きになるように並列接続したらどうなるのだろうか？

その場合、合成容量に蓄えられた電荷Qは

(%i50) e2: Q=C*(E1+E2);
(%o50) Q=C*(E2+E1)

となり、同様に静電エネルギーも

(%i51) e3: W=Q*(E2+E1)/2;
(%o51) W=((E2+E1)*Q)/2

となる。これでC,Q,Wを解くと

(%i52) solve([e1,e2,e3],[C,Q,W]);
(%o52) [[C=(C1*C2)/(C2+C1),Q=(C1*C2*(E2+E1))/(C2+C1),W=(C1*C2*(E2^2+2*E1*E2+E1^2))/(2*C2+2*C1)]]

因数分解すると

(%i54) factor(%);
(%o54) [[C=(C1*C2)/(C2+C1),Q=(C1*C2*(E2+E1))/(C2+C1),W=(C1*C2*(E2+E1)^2)/(2*(C2+C1))]]

E1の極性が逆になるだけだということがわかる。

実は(E2-E1)^2は(E1-E2)^2と同じである。MaximaはE2^2-2*E1*E2+E1^2というのを因数分解すると(E2-E1)^2のほうを表示する。E2^2-2*E1*E2+E1^2はE1^2-2*E1*E2+E2^2と書いたのと同じなので(E1-E2)^2にも因数分解できるがこちらはMaximaでは出てこない。

今度は予め充電されている電荷が判明している２つの異なるコンデンサを並列接続した場合に失われる静電エネルギーの式を導くもの。



著者の解法と違うやり方で。基本的には前の問題４５で使ったのと同じ考え方。今度は電荷が予めわかっているのでそれから電圧を割り出して２つのコンデンサを直列に接続した状態でその合成容量を持つコンデンサの両端に蓄えられている静電エネルギーを求めれば良い。

(%i1) e1: E1=Q1/C1;
(%o1) E1=Q1/C1
(%i2) e2: E2=Q2/C2;
(%o2) E2=Q2/C2
(%i3) e3: C=(1/(1/C1+1/C2));
(%o3) C=1/(1/C2+1/C1)
(%i4) e4: W=C*(E1-E2)^2/2;
(%o4) W=(C*(E1-E2)^2)/2

これをW,C,E1,E2について解くと

(%i5) solve([e1,e2,e3,e4],[W,C,E1,E2]);
(%o5) [[W=(C1^2*Q2^2-2*C1*C2*Q1*Q2+C2^2*Q1^2)/(2*C1*C2^2+2*C1^2*C2),C=(C1*C2)/(C2+C1),E1=Q1/C1,E2=Q2/C2]]
(%i6) factor(%);
(%o6) [[W=(C1*Q2-C2*Q1)^2/(2*C1*C2*(C2+C1)),C=(C1*C2)/(C2+C1),E1=Q1/C1,E2=Q2/C2]]

ということで著者と同じ解が得られる。

今度はそれぞれ電荷Q充電された異なる３つのコンデンサを並列に接続した場合に損失（移動）する静電エネルギーを求めるもの。



著者とは違うアプローチで解くために、少しへそ曲がりな見方をする。

最初に同じ電荷Qが蓄えられたC1とC2を並列接続して失われる静電エネルギーをW12とする。ついで並列に接続されたC1とC2の両端の電圧をE12として更にC3をそれに並列に接続すると失われる静電エネルギーに先のW12を加えたものをWとすると以下の関係が成り立つ。

(%i55) e1: E1=Q/C1;
(%o55) E1=Q/C1
(%i56) e2: E2=Q/C2;
(%o56) E2=Q/C2
(%i57) e3: E3=Q/C3;
(%o57) E3=Q/C3
(%i58) e4: C12=1/(1/C1+1/C2);
(%o58) C12=1/(1/C2+1/C1)
(%i59) e5: W12=C12*(E1-E2)^2/2;
(%o59) W12=(C12*(E1-E2)^2)/2
(%i60) e6: E12=2*Q/(C1+C2);
(%o60) E12=(2*Q)/(C2+C1)
(%i61) e7: C=1/(1/(C1+C2)+1/C3);
(%o61) C=1/(1/C3+1/(C2+C1))
(%i66) e8: W=C*(E12-E3)^2/2+W12;
(%o66) W=W12+(C*(E12-E3)^2)/2

これらからE1,E2,E3,E12,C12,W12,C,Wを解くと

(%i67) solve([e1,e2,e3,e4,e5,e6,e7,e8],[E1,E2,E3,E12,C12,W12,C,W]);
(%o67) [[E1=Q/C1,E2=Q/C2,E3=Q/C3,E12=(2*Q)/(C2+C1),C12=(C1*C2)/(C2+C1),W12=((C2^2-2*C1*C2+C1^2)*Q^2)/(2*C1*C2^2+2*C1^2*C2),C=((C2+C1)*C3)/(C3+C2+C1),
W=(((C2+C1)*C3^2+(C2^2-6*C1*C2+C1^2)*C3+C1*C2^2+C1^2*C2)*Q^2)/(2*C1*C2*C3^2+(2*C1*C2^2+2*C1^2*C2)*C3)]]

因数分解すると

(%i68) factor(%);
(%o68) [[E1=Q/C1,E2=Q/C2,E3=Q/C3,E12=(2*Q)/(C2+C1),C12=(C1*C2)/(C2+C1),W12=((C2-C1)^2*Q^2)/(2*C1*C2*(C2+C1)),C=((C2+C1)*C3)/(C3+C2+C1),W=
((C2*C3^2+C1*C3^2+C2^2*C3-6*C1*C2*C3+C1^2*C3+C1*C2^2+C1^2*C2)*Q^2)/(2*C1*C2*C3*(C3+C2+C1))]]

これは著者と等価な解である。

コンデンサに関する問題は終わって、今度はもうひとつのブリッジ回路の問題。



左右対称なブリッジ回路でそれぞれE1とE2の異なる電圧の電源が印可されている。ここで中央のR3に流れる電流I3が0となる条件を求めるもの。

とりあえずいつもの分流法で方程式をたててみる。

(%i88) e1: I1*R1+I3*R3+I1*R1=E1;
(%o88) I3*R3+2*I1*R1=E1
(%i89) e2: I2*R2-I3*R3+I2*R2=E2;
(%o89) 2*I2*R2-I3*R3=E2

また

(%i92) e3: I1=I3+I2;
(%o92) I1=I3+I2

なので、これらからI1,I2,I3を解くと

(%i93) solve([e1,e2,e3],[I1,I2,I3]);
(%o93) [[I1=((E2+E1)*R3+2*E1*R2)/((2*R2+2*R1)*R3+4*R1*R2),I2=((E2+E1)*R3+2*E2*R1)/((2*R2+2*R1)*R3+4*R1*R2),I3=-(E2*R1-E1*R2)/((R2+R1)*R3+2*R1*R2)]]

因数分解すると

(%i94) factor(%);
(%o94) [[I1=(E2*R3+E1*R3+2*E1*R2)/(2*(R2*R3+R1*R3+2*R1*R2)),I2=(E2*R3+E1*R3+2*E2*R1)/(2*(R2*R3+R1*R3+2*R1*R2)),I3=(E1*R2-E2*R1)/(R2*R3+R1*R3+2*R1*R2)]]

I3が0になるためには分子が0とならなければならない

従って

E1*R2-E2*R1=0

∴E1*R2=E2*R1

となる。

最初電源の方向を見間違えていてちょっと違う解が出て来て焦った。

２つのΔ接続抵抗回路を間に挟んでE1とE2の電源が供給されている場合、E2の電源を殺す（電流が流れないようにする）R1/R2の比を求めるという問題。



深く考えずにE2の電源から流れる電流Ie2を求めるために方程式をたてて解いてみた。

(%i1) e1: E1=(Ie1-I1)*R1+(Ie1+Ie2-I2)*2*R2;
(%o1) E1=2*(-I2+Ie2+Ie1)*R2+(Ie1-I1)*R1
(%i2) e2: E2=(I1+Ie2)*2*R1+I2*R2;
(%o2) E2=I2*R2+2*(I1+Ie2)*R1
(%i3) e3: I1*R1+(I1+Ie2)*2*R1=(Ie1-I1)*R1;
(%o3) 2*(I1+Ie2)*R1+I1*R1=(Ie1-I1)*R1
(%i4) e4: I2*R2+(I2-Ie2)*R2=(Ie1+Ie2-I2)*2*R2;
(%o4) (I2-Ie2)*R2+I2*R2=2*(-I2+Ie2+Ie1)*R2

これをI1,I2,Ie1,Ie2について解くと

(%i5) solve([e1,e2,e3,e4],[I1,I2,Ie1,Ie2]);
(%o5) [[I1=((7*E1-10*E2)*R2+(8*E1-8*E2)*R1)/(8*R2^2+17*R1*R2+8*R1^2),I2=(8*E2*R2+(5*E2+2*E1)*R1)/(8*R2^2+17*R1*R2+8*R1^2),Ie1=((12*E1-8*E2)*R2+(16*E1-8*E2)*R1)/(8*R2^2+17*R1*R2+8*R1^2)
,Ie2=-((8*E1-16*E2)*R2+(8*E1-12*E2)*R1)/(8*R2^2+17*R1*R2+8*R1^2)]]
(%i6) factor(%);
(%o6) [[I1=-(10*E2*R2-7*E1*R2+8*E2*R1-8*E1*R1)/(8*R2^2+17*R1*R2+8*R1^2),I2=(8*E2*R2+5*E2*R1+2*E1*R1)/(8*R2^2+17*R1*R2+8*R1^2),Ie1=-
(4*(2*E2*R2-3*E1*R2+2*E2*R1-4*E1*R1))/(8*R2^2+17*R1*R2+8*R1^2),Ie2=(4*(4*E2*R2-2*E1*R2+3*E2*R1-2*E1*R1))/(8*R2^2+17*R1*R2+8*R1^2)]]

Ie2が0となるためには分子が0にならなければならないので

4*E2*R2-2*E1*R2+3*E2*R1-2*E1*R1=0

R1とR2の共通項を整理すると

(4*E2-2*E1)*R2+(3*E2-2*E1)*R1=0

(4*E2-2*E1)*R2=(2*E1-3*E2)*R1

故に

R1/R2=(4*E2-2*E1)/(2*E1-3*E2)

ということで著者の解と同じ結果が得られた。

あっさり流したKelvinのダブルブリッジ。

実は電気工学の歴史上重要な意味を持つ回路だったりする。

教科書にはもう古すぎてどこもKelvinのダブルブリッジ以上のことは説明されていない。

Kelvinとはそれを考案した人の名前だろうというのは想像がつく。

実は電気工学や熱力学の黎明期に登場した英国の天才学者、ウイリアム・トムソンことKelvin卿であることは想像に難く無い。

Kelvin卿は生涯８００もの論文を発表し、電気工学や熱力学で数々の重要な発見をしてきた人である。特に熱力学の第二法則はKelvin卿によるものであり、絶対温度の単位(K)はKelvinのKである。

電気の分野でも意欲的に発見や数々の理論を生み出して多大な影響力を持った人だったらしい。日本の電気工学の父と言われる若くして夭折した天才学者、志田林三郎も英国に留学してKelvin卿から直伝を受けて数々の賞を獲得したらしい。

Kelvin卿は熱力学や電気など科学についてどん欲に知識を追求していったところもあり、反面悲観的な予測を発表してマイナスの影響力を発揮することも多かったらしい。

ブリッジ回路に使われる検流計の開発もお得意のものだったらしい。というのも当時発明されたばかりの電信技術でドーバー海峡や大西洋を橋渡しする海底ケーブルの計画が次々とたてられていた時代であった。

Kelvin卿は当時初めての電信方程式というのを発表し、長大な海底ケーブルでは電線の抵抗と長さによって波形が鈍り実用にならないという根拠を示したことでも有名である。当時の電信技術はケーブルに電流を流して末端に接続された検流計かリレーを動かすことによって符号を伝送するというものだった。

Kelvin卿は大西洋ケーブル施設の計画に参加した一人であり、主にケーブルの電気抵抗の低減に腐心したようだ。微弱な電流でも符号が確実に伝えられるように微弱な電流で大きく動く鏡を使った検流計（ミラー・ガルバノメーター）を考案したりもした。

おそらくその検流計と電線のように低い電気抵抗値を正確に測定するためについでに考案したのがダブルブリッジ回路であろうと推測される。この回路はまともなデジタルマルチメーターとかの抵抗測定機能には必ず４端子測定モードがついていると思うが、それに使われている。通常の２端子や単純なブリッジ回路による測定では微少な抵抗値を測定する場合に、回路の配線抵抗が無視できなくなり精度が悪化する。ダブルブリッジ回路では抵抗の比だけで決まるので配線の抵抗で影響を受けなくなるという利点がある。

たぶんこのダブルブリッジ回路で銅線を曲げると抵抗値がわずかに増えるという発見をしたのだろう。現代でも使われている歪みゲージセンサーの原理でもある。

問題５０でいきなり行き詰まった。

問題そのものは当たり前の結論を導くものだが、著者の解法はなんの前触れもなく偏微分の式を導いている。

学生時代、あこがれだった電気科の学生に授業の事を聞いたら「まだ数学で習っても居ない微分積分が出てきて泣いた」と漏らしているのを聞いたことがある。

このことだったのか。電気回路の解析には回路を数式モデルに置き換えて数式処理や微積分を駆使することが当たり前になっているのだが、学校では数学のカリキュラムと工学のカリキュラムは必ずしも同期していない。特に微積分は後になって習うので、初等の専門教科である回路解析Iとかでいきなり微分や積分を使った解析を学ばなければならないという状況らしい。これはたぶん今も変わらないだろう。

先に数学を勉強すると専門を教えている時間が無いしということで、数年の限られた期間ですべてを教えるというのにはどうしても数学と工学がパラにやらないといけない。結果的にどちらも身につかないということになる。

結局工学を極めるには自分で数学もやり直さないといけないことになるわけで。

数学の記号とかは憶えているけど何も身についていない。解析幾何とかベクトル解析とか教科書を買わされたのは憶えているが、どういうことだったのかは記憶にない。

今思うにどれも物理学とか電磁気学とかの先端の科学を理解し研究するには必須の数学スキルだということは確か。確かに物理学の授業で波動方程式とかを教わった憶えはあるけど、身についているわけでもなく。意味も最後までわからなかった。

これからやり直しである。

こんな初等の回路解析で躓いていては電磁気学をマスターできるのはいつのことになるやら。

とりあえず問題にあるEabの式を求めてみることにする。



(%i16) e1;
(%o16) E=r*I+Eab
(%i17) e2;
(%o17) I1*(R0-x)=x*(I-I1)
(%i18) e3;
(%o18) Eab=I1*(R0-x)
(%i19) e4: E=R*I+r*I;
(%o19) E=I*R+r*I

これらの式が成り立つのでI,I1,Eab,Rについて解いてみると

(%i20) solve([e1,e2,e3,e4],[I,I1,Eab,R]);
(%o20) [[I=(E*R0)/((x+r)*R0-x^2),I1=(x*E)/((x+r)*R0-x^2),Eab=(x*E*R0-x^2*E)/((x+r)*R0-x^2),R=(x*R0-x^2)/R0]]

ということで合成抵抗は著者の解に出てくるのと一緒である。

しかしEabの式は二次関数になっていてちょっと目では最大値条件がわからない。

著者の場合、合成抵抗が最大になればEabも最大になるという点に着眼して簡単に解いている。

同じやり方をやっても仕方が無いので、難易度の高いEabの式に着目してみることにする。

Eabをxの関数としてその導関数を求めれば接線の傾きの式が得られる。その傾きが０となるxを求めれば、曲線の頂点であるので最大値であると言える。

だがこれが難題である。Eabの式を見ると分子と分母の２つの式からなる。こうした式の導関数は以下のように公式で決まっている。

(g(x)/f(x))'=(g'(x)f(x)-g(x)f'(x))/f(x)^2

従って

g(x)=x*E*R0-x^2*E
f(x)=(x+r)*R0-x^2

とすると

g'(x)=E*R0-2*x*E
f'(x)=R0-2*x

これをそれぞれ置き換えると

(g(x)/f(x))'=((E*R0-2*x*E)*((x+r)*R0-x^2)-(x*E*R0-x^2*E)*(R0-2*x))/((x+r)*R0-x^2)^2

面倒なのでMaximaで整理させると

(%i28) ((E*R0-2*x*E)*((x+r)*R0-x^2)-(x*E*R0-x^2*E)*(R0-2*x))/((x+r)*R0-x^2)^2;
(%o28) (((x+r)*R0-x^2)*(E*R0-2*x*E)-(R0-2*x)*(x*E*R0-x^2*E))/((x+r)*R0-x^2)^2
(%i29) factor(%);
(%o29) (r*E*R0*(R0-2*x))/(x*R0+r*R0-x^2)^2

ということになり

Eab'=(r*E*R0*(R0-2*x))/(x*R0+r*R0-x^2)^2

ここでEab'が０になるには

R0-2*x=0

であればいいので

すなわち

x=R0/2

ということになる。

著者と同じ答えが得られた。

次ぎも微分を応用して解く問題。



合成抵抗Rabは

(%i1) e1: Rab=1/(1/(R1+x)+1/R4+1/(R2-x+R3));
(%o1) Rab=1/(1/R4+1/(R3+R2-x)+1/(R1+x))
(%i2) ratsimp(%);
(%o2) Rab=(((R1+x)*R3+(R1+x)*R2-x*R1-x^2)*R4)/((R3+R2+R1)*R4+(R1+x)*R3+(R1+x)*R2-x*R1-x^2)

という具合に複雑極まり無い。

これを微分して一次の導関数を求める。前の問題と同様に手計算でもできないことはないが、Maximaには導関数を求める機能があるのでそれを使ってみる。

(%i9) diff(%,x);
(%o9) 0=((R3+R2-x)*R4)/(R3*R4+R2*R4+R1*R4+R1*R3+x*R3+R1*R2+x*R2-x*R1-x^2)-
((R1+x)*R4)/(R3*R4+R2*R4+R1*R4+R1*R3+x*R3+R1*R2+x*R2-x*R1-x^2)-((R1+x)*(R3+R2-x)*(R3+R2-R1-2*x)*R4)/(R3*R4+R2*R4+R1*R4+R1*R3+x*R3+R1*R2+x*R2-x*R1-x^2)^2
(%i10) factor(%);
(%o10) 0=((R3+R2-R1-2*x)*(R3+R2+R1)*R4^2)/(R3*R4+R2*R4+R1*R4+R1*R3+x*R3+R1*R2+x*R2-x*R1-x^2)^2

ということで導関数が0の値を取るには分子の式が0になればよいので、

R3+R2-R1-2*x=0

から

x=(R3+R2-R1)/2

これで先の合成抵抗の式のxを置き換えると、

(%o11) Rab=((-(R3+R2-R1)/2+R3+R2)*((R3+R2-R1)/2+R1)*R4)/(R3*R4+R2*R4+R1*R4-(R3+R2-R1)^2/4+(R3*(R3+R2-R1))/2+(R2*(R3+R2-R1))/2-(R1*(R3+R2-R1))/2+R1*R3+R1*R2)
(%i12) factor(%);
(%o12) Rab=((R3+R2+R1)*R4)/(4*R4+R3+R2+R1)

従って最大の合成抵抗Rmは

Rm=((R3+R2+R1)*R4)/(4*R4+R3+R2+R1)

となり著者の解法と同じ結果が得られた。