問題３４は今までのブリッジ回路を題材にした問題とは趣向が異なっている。

まず電源の位置が抵抗R1と直列となる場所に入っていること。

通常電源が接続されているブリッジの対角位置にスイッチが接続されていること。

問題の趣旨はスイッチを閉じても開いても剣流計に流れる電流が一定の場合には４つの抵抗の間にブリッジ回路の平衡条件と同じ条件が成り立つことを証明するという数学的な問題。

著者の解答例以外に解き方が思いつかなくていろいろ悩んだ。著者の例ではスイッチが閉じた時と開いたときとでそれぞれ回路を描いて、それぞれについて剣流計に流れる電流の式を導き出して、その２つの電流が等しくなる４つの抵抗値の条件を見つけ出すという方法。

これをなぞってもかなり数式の処理が面倒なので練習にはなるが、へそ曲がりなので著者とは違う方法でスイッチが閉じている時と開いている時のそれぞれの剣流計に流れる電流の式を導きだしてみよう。

それにはまず著者と違って、以下のような回路としてとらえスイッチを一つの抵抗(Rc)とみなし抵抗値によって閉じている時（抵抗値が０）と開いている時（抵抗値が∞）の両方に使える一般式を導き出す。



上の回路ではキルヒホッフの法則により以下の式が成り立つ。

I1*R1 + Ig*Rg + (I1 - Ic)*R3 = E
I1*R1 + (I1 - Ig)*R2 + (I1 - Ig - Ic)*R4 + (I1 - Ic)*R3 = E
I1*R1 + (I1 - Ig)*R2 + Ic*Rc = E

これをMaximaでI1,Ig,Icについて解くと、

(%i2) e1: I1*R1+Ig*Rg+(I1-Ic)*R3=E;
(%o2) (I1-Ic)*R3+I1*R1+Ig*Rg=E
(%i3) e2: I1*R1+(I1-Ig)*R2+(I1-Ig-Ic)*R4+(I1-Ic)*R3=E;
(%o3) (I1-Ig-Ic)*R4+(I1-Ic)*R3+(I1-Ig)*R2+I1*R1=E
(%i4) e3: I1*R1+(I1-Ig)*R2+Ic*Rc=E;
(%o4) (I1-Ig)*R2+I1*R1+Ic*Rc=E
(%i5) solve([e1,e2,e3],[I1,Ig,Ic]);
(%o5) [[I1=
(E*(Rg*(R4+Rc)+(R2+Rc)*R4+Rc*R2)+E*R3*(R4+R2+Rg))/(R3*(R1*(R4+R2+Rg)+(R2+Rc)*R4+Rg*(R2+Rc)+Rc*R2)+R1*(Rg*(R4+Rc)+(R2+Rc)*R4+Rc*R2)+Rg*((R2+Rc)*R4+Rc*R2)),Ig
=(E*((R2+Rc)*R4+Rc*R2)+E*R2*R3)/(R3*(R1*(R4+R2+Rg)+(R2+Rc)*R4+Rg*(R2+Rc)+Rc*R2)+R1*(Rg*(R4+Rc)+(R2+Rc)*R4+Rc*R2)+Rg*((R2+Rc)*R4+Rc*R2)),
Ic=(E*R3*(R4+R2+Rg)+Rg*E*R4)/(R3*(R1*(R4+R2+Rg)+(R2+Rc)*R4+Rg*(R2+Rc)+Rc*R2)+R1*(Rg*(R4+Rc)+(R2+Rc)*R4+Rc*R2)+Rg*((R2+Rc)*R4+Rc*R2))
]]

Igの式をRcに関して少し整理すると、

Ig=(E*(R2*R4+Rc*R4+R2*R3+Rc*R2))/(R2*R3*R4+R1*R3*R4+Rc*R3*
R4+R1*R2*R4+Rg*R2*R4+Rg*R1*R4+Rc*R1*R4+Rc*Rg*R4+R1*R2*R3+Rg*R2*R3+Rc*R2*R3+Rg*R1*R3+Rc*Rg*R3+
Rc*R1*R2+Rc*Rg*R2+Rc*Rg*R1)
=(E*(Rc*(R4+R2)+R2*(R4+R3))/(Rc*(R3*R4+R1*R4+Rg*R4+R2*R3+Rg*R3+R1*R2+Rg*R2+Rg*R1)+R2*R3*R4+R1*R3*R4+R1*R2*R4+Rg*R2*R4+Rg*R1*R4+R1*R2*R3+Rg*R2*R3+Rg*R1*R3)
=(E*(Rc*(R4+R2)+R2*(R4+R3))/(Rc*((R3+R1)*(R4+R2)+Rg*(R4+R3+R2+R1))+R3*R4*(R2+R1)+(R4+R3)*(R1*R2+Rg*R2+Rg*R1))

上記の式からスイッチが閉じたとき(Rc=0)の時の剣流計に流れる電流をIg1とすると、

Ig1=(E*(0*(R4+R2)+R2*(R4+R3))/(0*((R3+R1)*(R4+R2)+Rg*(R4+R3+R2+R1))+R3*R4*(R2+R1)+(R4+R3)*(R1*R2+Rg*R2+Rg*R1))
=(E*R2*(R4+R3))/(R3*R4*(R2+R1)+(R4+R3)*(R1*R2+Rg*R2+Rg*R1))

スイッチが開いた時(Rc=∞）の時の剣流計に流れる電流をIg2とすると、まず分子と分母を先にそれぞれRcで割り、次ぎにRcを∞とすると1/Rcは０となることから、

Ig2=(E*((R4+R2)+R2*(R4+R3)/Rc))/(((R3+R1)*(R4+R2)+Rg*(R4+R3+R2+R1))+R3*R4*(R2+R1)/Rc+(R4+R3)*(R1*R2+Rg*R2+Rg*R1)/Rc)
=(E*((R4+R2)+0))/(((R3+R1)*(R4+R2)+Rg*(R4+R3+R2+R1)+0+0)
=((R4+R2)*E)/((R3+R1)*(R4+R2)+Rg*(R4+R3+R2+R1))

Ig1とIg2はそれぞれ著者の解答例と同じ式が得られている。

ここでIg1とIg2が等しいとすると

Ig1-Ig2=0が成り立つので、これをMaximaで整理すると、

(%i40)
(E*R2*(R4+R3))/(R3*R4*(R2+R1)+(R4+R3)*(R1*R2+Rg*R2+Rg*R1))-((R4+R2)*E)/((R3+R1)*(R4
+R2)+Rg*(R4+R3+R2+R1))=0;
(%o40) (E*R2*(R4+R3))/((R1*R2+Rg*R2+Rg*R1)*(R4+R3)+(R2+R1)*R3*R4)-(E*(R4+R2))/(Rg*(R4+R3+R2+R1)+(R3+R1)*(R4+R2))=0
(%i42) factor(%);
(%o42) -(E*(R1*R4-R2*R3)*(R3*R4+Rg*R4+R2*R3+Rg*R3))/(
(R3*R4+R1*R4+Rg*R4+R2*R3+Rg*R3+R1*R2+Rg*R2+Rg*R1)*
(R2*R3*R4+R1*R3*R4+R1*R2*R4+Rg*R2*R4+Rg*R1*R4+R1*R2*R3+Rg*R2*R3+Rg*R1*R3))=0

最後の式の負号を取って整理すると、

(E*(R2*R3-R1*R4)*(R3*R4+Rg*R4+R2*R3+Rg*R3))/(
(R3*R4+R1*R4+Rg*R4+R2*R3+Rg*R3+R1*R2+Rg*R2+Rg*R1)*
(R2*R3*R4+R1*R3*R4+R1*R2*R4+Rg*R2*R4+Rg*R1*R4+R1*R2*R3+Rg*R2*R3+Rg*R1*R3))=0

従って上記の式が成り立つためには、

R2*R3-R1*R4=0でなければならない。

すなわち

R2*R3=R1*R4

というブリッジ回路の平衡条件と同じことが証明できた。

問題３５はブリッジ回路だけれども理想的な剣流計をつないだ場合に内部抵抗は０となり短絡したのと同じになる。その場合に剣流計に流れる電流を求めるもの。

著者の解答例ではブリッジが短絡することによって単純な並列抵抗回路を直列に接続した回路になることを見いだして合成抵抗を求め更に分流則によって各抵抗に流れる電流を求めその差分として短絡部分に流れている電流を求めている。はっきり言って面倒である。

以下の回路を描いてMaximaを使えば普通に方程式をたてて解けば一発で答えが出る。



(%i1) e1: (I-I1)*n*R2+(I-I1-Ia)*R2=E;
(%o1) (-I1+I-Ia)*R2+n*(I-I1)*R2=E
(%i2) e2: (I-I1)*n*R2+(I1+Ia)*m*R1=E;
(%o2) n*(I-I1)*R2+m*(I1+Ia)*R1=E
(%i3) e3: I1*R1+(I1+Ia)*m*R1=E;
(%o3) m*(I1+Ia)*R1+I1*R1=E
(%i4) solve([e1,e2,e3],[I,I1,Ia]);
(%o4) [[I=(n*E*R2^2+E*(m*n*R1+R1)*R2+m*E*R1^2)/((m+1)*n*R1*R2^2+(m*n*R1^2+m*R1^2)*R2),I1=(n*E*R2+m*n*E*R1)/((m+1)*n*R1*R2+m*n*R1^2+m*R1^2),Ia=-((m*n-1)*E)/((m+1)*n*R2+m*n*R1+m*R1)
]]

Iaの向きが逆だが

Ia=-((m*n-1)*E)/((m+1)*n*R2+m*n*R1+m*R1)
=-((m*n-1)*E)/(m*n*(R1+R2)+m*R1+n*R2)

となり著者の解と同等の結果が得られた。

この問題は一見するとＴ型アッテネーター回路を抵抗バイパスを追加したような回路。



著者の模範解答ではこれがブリッジ回路であることに着眼し、かつブリッジの平衡条件を満たすことから抵抗Rbに流れる電流が０であることを利用して抵抗Rbが挿入されていない形に簡略化して解いている。

同じやり方をしても仕方が無いので違うやり方で強引に解いてみた。

いつもの通りに分流法で方程式を立てMaximaで解いてみると。

(%i1) e1: I1*R+Ec=E;
(%o1) I1*R+Ec=E
(%i2) e2: Ia*Ra+(Ia-Ib)*R=E;
(%o2) (Ia-Ib)*R+Ia*Ra=E
(%i3) e3: Ia*Ra+Ib*Rb+Ec=E;
(%o3) Ib*Rb+Ia*Ra+Ec=E
(%i4) e4: I=I1+Ia;
(%o4) I=I1+Ia
(%i5) e5: I=(Ia-Ib)+Ec/Rc;
(%o5) I=Ec/Rc-Ib+Ia
(%i7) solve([e1,e2,e3,e4,e5],[I,I1,Ia,Ib,Ec]);
(%o7) [[I=(E*R^2+(Rc+2*Rb+Ra)*E*R+(Ra*(Rc+Rb)+Rb*Rc)*E)/((Rc+Rb+Ra)*R^2+(Ra*(2*Rc+Rb)+Rb*Rc)*R+Ra*Rb*Rc),I1=
((Rb+Ra)*E*R+Ra*(Rc+Rb)*E)/((Rc+Rb+Ra)*R^2+(Ra*(2*Rc+Rb)+Rb*Rc)*R+Ra*Rb*Rc),Ia=(E*R^2+(Rc+Rb)*E*R+Rb*Rc*E)/((Rc+Rb+Ra)*R^2+(Ra*(2*Rc+Rb)+Rb*Rc)*R+Ra*Rb*Rc),Ib=
(E*R^2-Ra*Rc*E)/((Rc+Rb+Ra)*R^2+(Ra*(2*Rc+Rb)+Rb*Rc)*R+Ra*Rb*Rc),Ec=(Rc*E*R^2+(Rb*Rc+Ra*Rc)*E*R+Ra*Rb*Rc*E)/((Rc+Rb+Ra)*R^2+(Ra*(2*Rc+Rb)+Rb*Rc)*R+Ra*Rb*Rc)]]
(%i8) factor(%);
(%o8) [[I=(E*(R^2+Rc*R+2*Rb*R+Ra*R+Rb*Rc+Ra*Rc+Ra*Rb))/(Rc*R^2+Rb*R^2+Ra*R^2+Rb*Rc*R+2*Ra*Rc*R+Ra*Rb*R+Ra*Rb*Rc),I1=
(E*(Rb*R+Ra*R+Ra*Rc+Ra*Rb))/(Rc*R^2+Rb*R^2+Ra*R^2+Rb*Rc*R+2*Ra*Rc*R+Ra*Rb*R+Ra*Rb*Rc),Ia=(E*(R+Rb)*(R+Rc))/(Rc*R^2+Rb*R^2+Ra*R^2+Rb*Rc*R+2*Ra*Rc*R+Ra*Rb*R+Ra*Rb*Rc)
,Ib=(E*(R^2-Ra*Rc))/(Rc*R^2+Rb*R^2+Ra*R^2+Rb*Rc*R+2*Ra*Rc*R+Ra*Rb*R+Ra*Rb*Rc),Ec=
(Rc*E*(R+Ra)*(R+Rb))/(Rc*R^2+Rb*R^2+Ra*R^2+Rb*Rc*R+2*Ra*Rc*R+Ra*Rb*R+Ra*Rb*Rc)]]

ここで抵抗Rbに流れる電流Ibの分子がE*(R^2-Ra*Rc)であり、Ra*Rc=R^2の場合Ibは0となることがわかる。

問題はEcの式が複雑で著者の解のように簡単ではないという点。

Ec=(Rc*E*(R+Ra)*(R+Rb))/(Rc*R^2+Rb*R^2+Ra*R^2+Rb*Rc*R+2*Ra*Rc*R+Ra*Rb*R+Ra*Rb*Rc)

この式ははたして著者の解にある

Ec=(Rc*E)/(R+Rc)

と等価なのだろうか？

そのためには分母の式が(R+Ra)*(R+Rb)で割り切れないといけないことになる。

すなわち

Ec=(Rc*E*(R+Ra)*(R+Rb))/((R+Ra)*(R+Rb)*(R+Rc))

と等価である必要がある。

果たして

(R+Ra)*(R+Rb)*(R+Rc)=(Rc*R^2+Rb*R^2+Ra*R^2+Rb*Rc*R+2*Ra*Rc*R+Ra*Rb*R+Ra*Rb*Rc)

かどうかというのが問題である。

実際にMaximaに計算させてみた

(%i26) (R+Ra)*(R+Rb)*(R+Rc);
(%o26) (R+Ra)*(R+Rb)*(R+Rc)
(%i27) expand(%);
(%o27) R^3+Rc*R^2+Rb*R^2+Ra*R^2+Rb*Rc*R+Ra*Rc*R+Ra*Rb*R+Ra*Rb*Rc

なんとなく部分的には一致しているが、R^3なんてのがある。

実はRa*Rc=R^2ということなのでR^3=Ra*Rc*Rに置き換えることができる。

(%i36) subst(Ra*Rc*R, R^3, R^3+Rc*R^2+Rb*R^2+Ra*R^2+Rb*Rc*R+Ra*Rc*R+Ra*Rb*R+Ra*Rb*Rc);
(%o36) Rc*R^2+Rb*R^2+Ra*R^2+Rb*Rc*R+2*Ra*Rc*R+Ra*Rb*R+Ra*Rb*Rc

ということで

(R+Ra)*(R+Rb)*(R+Rc)=(Rc*R^2+Rb*R^2+Ra*R^2+Rb*Rc*R+2*Ra*Rc*R+Ra*Rb*R+Ra*Rb*Rc)

であることが確かめられた

従って

Ec=Rc*E/(R+Rc)

ということになる。

Kelvinのダブルブリッジというのは基本系のブリッジ回路の一端に抵抗のΔ接続を挿入した形になっている。



著者の解ではΔ接続をY接続に置換して基本形のブリッジ回路に簡略化してから式を立てている。

Maximaがあればどんな複雑な回路でもたちどころに解けるので、そのままの回路で方程式をたててみて解いてみることにする。

まずキルヒホッフの法則により以下の５つの式が成り立つ。

(%i1) e1: E=I1*R1+(I1-Ig)*R2;
(%o1) E=(I1-Ig)*R2+I1*R1
(%i2) e2: E=(I-I1)*Rx+(I-I1-I4)*R6+(I-I1+Ig)*R3;
(%o2) E=(-I4-I1+I)*R6+(-I1+I+Ig)*R3+Rx*(I-I1)
(%i3) e3: E=I1*R1+Ig*Rg+(I4+Ig)*R5+(I-I1+Ig)*R3;
(%o3) E=(I4+Ig)*R5+(-I1+I+Ig)*R3+I1*R1+Ig*Rg
(%i4) e4: E=(I-I1)*Rx+I4*R4+(I4+Ig)*R5+(I-I1+Ig)*R3;
(%o4) E=(I4+Ig)*R5+I4*R4+(-I1+I+Ig)*R3+Rx*(I-I1)
(%i5) e5: E=(I-I1)*Rx+I4*R4-Ig*Rg+(I1-Ig)*R2;
(%o5) E=I4*R4+(I1-Ig)*R2+Rx*(I-I1)-Ig*Rg


上記の式からI,I1,I4,Ig,Rxに関する一般解を解くことができるが、問題ではさらにブリッジが平衡状態にある場合に限定しているので、以下の式を加える必要がある。

(%i8) e6: I1*R1=(I-I1)*Rx+I4*R4;
(%o8) I1*R1=I4*R4+Rx*(I-I1)

これらの６つの式からI,I1,I4,Ig,Rxを解くと、

(%i9) solve([e1,e2,e3,e4,e5,e6],[I,I1,I4,Ig,Rx]);
(%o9) [[I=((E*R5+E*R3+E*R2)*R6+(E*R3+E*R2)*R5+(E*R3+E*R2)*R4)/(((R2+R1)*R5+(R2+R1)*R3)*R6+(R2+R1)*R3*R5+(R2+R1)*R3*R4),I1=E/(R2+R1),I4=
(E*R2*R6)/(((R2+R1)*R5+(R2+R1)*R3)*R6+(R2+R1)*R3*R5+(R2+R1)*R3*R4),Ig=0,Rx=((R1*R5-R2*R4+R1*R3)*R6+R1*R3*R5+R1*R3*R4)/(R2*R6+R2*R5+R2*R4)]
]

という具合に瞬時に答えが出る。Ig=0になっているので平衡状態であることは確か。しかしRxの式が以下の著者の解に比べて複雑である。

Rx=R1*R3/R2+(R1/R2-R4/R5)*R5*R6/(R4+R5+R6)

はたして

R1*R3/R2+(R1/R2-R4/R5)*R5*R6/(R4+R5+R6)=((R1*R5-R2*R4+R1*R3)*R6+R1*R3*R5+R1*R3*R4)/(R2*R6+R2*R5+R2*R4)

であるかが問題である。これもMaximaで確認してみよう。

(%i10) R1*R3/R2+(R1/R2-R4/R5)*R5*R6/(R4+R5+R6);
(%o10) ((R1/R2-R4/R5)*R5*R6)/(R6+R5+R4)+(R1*R3)/R2
(%i11) factor(%);
(%o11) (R1*R5*R6-R2*R4*R6+R1*R3*R6+R1*R3*R5+R1*R3*R4)/(R2*(R6+R5+R4))
(%i12) expand(%);
(%o12) (R1*R5*R6)/(R2*R6+R2*R5+R2*R4)-(R2*R4*R6)/(R2*R6+R2*R5+R2*R4)+(R1*R3*R6)/(R2*R6+R2*R5+R2*R4)+(R1*R3*R5)/(R2*R6+R2*R5+R2*R4)+(R1*R3*R4)/(R2*R6+R2*R5+R2*R4)

ということで一見してまったく違うように見える著者の式とMaximaが出した式は同じものだったということが確認できた。

残る問題はR6の値によらずブリッジが平衡であるためのその他の抵抗値の関係を求めるというもの。これは著者と同じようにブリッジが平衡状態の時のRxの関係式でR6の値によらず式が成立するための条件を見いだすことによって行う。元となるRxの式はMaximaが出力した

Rx=((R1*R5-R2*R4+R1*R3)*R6+R1*R3*R5+R1*R3*R4)/(R2*R6+R2*R5+R2*R4)

を使用する。著者と同様にR6の項を整理すると、

(Rx*R2-(R1*R5-R2*R4+R1*R3))*R6=(R5+R4)*R1*R3-(R5+R4)*Rx*R2

この式がR6の値によらず成り立つには

Rx*R2-(R1*R5-R2*R4+R1*R3)=0
かつ
(R5+R4)*R1*R3-(R5+R4)*Rx*R2=0
である必要がある。

最後の式の両辺を(R5+R4)で割ると

R1*R3-Rx*R2=0

すなわち

R1*R3=Rx*R2

∴R1/R2=Rx/R3

上記のRxとR1,R2,R3の関係式でもう片方の条件式を置き換えると

Rx=R1*R3/R2

Rx*R2-(R1*R5-R2*R4+R1*R3)=(R1*R3/R2)*R2-(R1*R5-R2*R4+R1*R3)=R1*R3-R1*R5+R2*R4-R1*R3=-R1*R5+R2*R4=0

すなわち

R2*R4=R1*R5

∴R4/R5=R1/R2

従って

R1/R2=Rx/R3=R4/R5

という著者と同じ結果が得られた。

ブリッジ回路の原理を利用して地絡地点までの距離を測定する方法。



例によってMaximaでブリッジが平衡条件の時の連立方程式を解いてみる。

(%i47) e1: E=I1*R1+(I1-Ig)*r*(L-x);
(%o47) E=I1*R1+r*(I1-Ig)*(L-x)
(%i48) e2: E=(I-I1)*R2+(I-I1+Ig)*r*x;
(%o48) E=(I-I1)*R2+r*x*(-I1+I+Ig)
(%i49) e3: E=I1*R1+Ig*Rg+(I-I1+Ig)*r*x;
(%o49) E=I1*R1+r*x*(-I1+I+Ig)+Ig*Rg
(%i50) e4: E=(I-I1)*R2-Ig*Rg+(I1-Ig)*r*(L-x);
(%o50) E=(I-I1)*R2+r*(I1-Ig)*(L-x)-Ig*Rg
(%i51) e5: I1*R1=(I-I1)*R2;
(%o51) I1*R1=(I-I1)*R2
(%i52) solve([e1,e2,e3,e4,e5],[I,I1,Ig,x]);
(%o52) [[I=(E*R2^2+2*E*R1*R2+E*R1^2)/(R1*R2^2+(R1^2+r*L*R1)*R2),I1=(E*R2+E*R1)/(R1*R2+R1^2+r*L*R1),Ig=0,x=(L*R2)/(R2+R1)]]

ということで著者と同じ解が得られた。

x=(L*R2)/(R2+R1)

さていよいよ問題も後半に突入（ってまだ後半だよ、まだ半分近く残ってる）

今度はキャパシタに関する問題。

最初はキャパシタを並列にしたら合成キャパシタはいくつになるかという簡単な問題。

しかし疑り深い症のある者にとってこの問題はくせ者である。

実学的には「コンデンサの並列接続＝容量の足し算」という既成概念が定着しているので、なんだこんな問題、次ぎいこ次ぎ。

となってしまいがちだが、ここで足を止めて基本に立ち返ろう。

コンデンサの容量とはなんぞや。

電荷（クーロン）の蓄え易さみたいな尺度かな。

コンデンサの両端に電圧Eが発生しているときは、容量(ファラッド）に電圧を乗じただけの電荷が蓄えられているとするというものだったと思う。

肝心なのは常に電荷が蓄えられていること。現実には蓄えるという手順が先に必要だが、コンデンサに最初電荷が蓄えられていない場合には電圧も０、そういうものにいきなり電圧をかけたら∞の電流が流れる計算になるが、すぐに電荷として蓄えられるので時間とともにコンデンサの両端の電圧は上昇して流れる電流も減ってくる、これは過渡現象を扱うことになるので、まだ１０年早い。それに実際の回路では電源は内部抵抗を持つし、配線にも抵抗やインダクタンスはあるので∞の電流が流れても逆に∞の電圧降下が発生して電流を制限することになるのでやっかいだ。また電荷が蓄えられたコンデンサを閉回路に挿入すれば電荷が流れて電流が発生する。電荷が流れると蓄えられている電荷が減るのでそれに比例して両端の電圧も減る。これは時間的に減っていくのでやはり過渡現象を扱うことになるのでまだ今は早過ぎる。

直流回路理論では定常電流（電流の時間的変化が０）ということが暗黙の前提である。それで回路を解析しやすくしている。

先のコンデンサの容量の定義からすれば、並列に接続された複数のコンデンサがそれぞれ電荷で満たされている状態では、それらのコンデンサに蓄えられた電荷の総量は以下のようになる。

Q = Q1+Q2+...+Qn

それぞれのコンデンサの電荷は

Q1 = C1*E, Q2 = C2*E, ... , Qn = Cn*E

で表されるので、

Q = (C1 + C2 + ... + Cn)*E

ということになる。従って合成容量Cで置き換えると

Q = C*E = (C1 + C2 + ... + Cn)*E

となり、C = (C1 + C2 + ... + Cn)
ということになる。

次ぎはコンデンサの直列接続。

これも深く考えると過渡現象の世界に入り込んでしまうので、定常電流の世界（電流変化が０）だけに限定して他は考えない。コンデンサを直列につないだだけでも、最初に電荷が蓄えられる時はどうなるのだとか想像したら夜も眠れなくなることうけあいだ。

これも合成容量を求める問題なので、最初に直列に接続されたコンデンサをそれらの合成容量をもった単一のコンデンサと考えることにする。とすれば合成容量を持った単一のコンデンサに蓄えられている電荷は

Q = C*E

となる。

とどのつまり個々のコンデンサはそれぞれ同一の電荷Qを蓄えてそれぞれ均衡を保っているということになる。そうでないと電荷の不均衡によって電流変化が生じてしまう。

著者の解答例ではいきなり説明もなくすべてのコンデンサが等しく電荷Qを持つということで解き始めているがこれはとまどう。

すべてのコンデンサに蓄えられている電荷がQであるとわかればそれぞれのコンデンサの両端の電圧は容量によって異なってくることになる。

Q = C1*E1 = C2*E2 = ... = Cn*En

ここでキルヒホッフの法則により直列に接続されたコンデンサの両端の電圧の総和は電源電圧に等しくなることから

E = E1 + E2 + ... + En

また先の電荷の式から

E1 = Q/C1, E2 = Q/C2, ... , En = Q/Cn

なのでこれで先のEの式を置き換えると

E = (Q/C1 + Q/C2 + ... + Q/Cn)

ここで

Q = C*E

から

C = Q/E

であるため、Eを先の式で置き換えると合成容量Cは

C = Q/(Q/C1 + Q/C2 + ... + Q/Cn)
=1/(1/C1 + 1/C2 + ... + 1/Cn)

ということになる。

各コンデンサの両端の電圧の比も

E1:E2:...:En = Q/C1:Q/C2:...:Q/Cn = 1/C1:1/C2:...:1/Cn

ということになる。

つまり直列に接続した場合、容量が少ないコンデンサほど電圧が高くなるということを意味する。容量が少ないのでそれだけ余分に電圧が高く印可された状態でないと電荷が均衡しないとも言える。

問題４０の応用というか、実際に容量値が与えられた場合のコンデンサの電圧を計算するというもの。



添え字の付いた式をMaximaでどう扱えばよいかわからなかったので問題３９と問題４０は著者と同じ解き方になってしまったが、今度はコンデンサの個数が有限なのでMaximでも解くことができる。

まず以下の式が成り立つ。

(%i1) e1: C=(1/(1/C1+1/C2));
(%o1) C=1/(1/C2+1/C1)
(%i2) e2: Q=C*E;
(%o2) Q=C*E
(%i6) e6: E1=Q/C1;
(%o6) E1=Q/C1
(%i7) e7: E2=Q/C2;
(%o7) E2=Q/C2

これらからQ,C,E1,E2の一般解を解くと

(%i10) solve([e1,e2,e6,e7],[Q,C,E1,E2]);
(%o10) [[Q=(C1*C2*E)/(C2+C1),C=(C1*C2)/(C2+C1),E1=(C2*E)/(C2+C1),E2=(C1*E)/(C2+C1)]]

あとはC1,C2,Eを実際の値に置き換えて計算すればよい。

(%i23) C1: 2*10^-6;
(%o23) 1/500000
(%i24) C2: 3*10^-6;
(%o24) 3/1000000
(%i25) E: 150;
(%o25) 150
(%i26) solve([e1,e2,e6,e7],[Q,C,E1,E2]);
(%o26) [[Q=9/50000,C=3/2500000,E1=90,E2=60]]
(%i27) float([[Q=9/50000,C=3/2500000,E1=90,E2=60]]), numer;
(%o27) [[Q=1.8000000000000001*10^-4,C=1.1999999999999999*10^-6,E1=90.0,E2=60.0]]

Cの値がfloatできっちり表現できない値なので致し方ないが。

コンデンサの直列と並列接続が混在している回路の計算。



これも連立方程式をたててMaximaで解ける。

(%i1) e1: C=1/(1/C2+1/(C1+C3)+1/C4);
(%o1) C=1/(1/C4+1/(C3+C1)+1/C2)
(%i2) e2: E=E2+E1+E4;
(%o2) E=E4+E2+E1
(%i3) e3: E=E2+E3+E4;
(%o3) E=E4+E3+E2
(%i4) e4: E1=Q1/C1;
(%o4) E1=Q1/C1
(%i5) e5: E2=Q2/C2;
(%o5) E2=Q2/C2
(%i6) e6: E3=Q3/C3;
(%o6) E3=Q3/C3
(%i7) e7: E4=Q4/C4;
(%o7) E4=Q4/C4
(%i9) e8: Q2=Q;
(%o9) Q2=Q
(%i10) e9: Q4=Q;
(%o10) Q4=Q
(%i12) e10: E=Q/C;
(%o12) E=Q/C

これをMaximaでC,Q,Q1,Q2,Q3,Q4,E1,E2,E3,E4について解くと。

(%i13) solve([e1,e2,e3,e4,e5,e6,e7,e8,e9,e10],[C,Q,Q1,Q2,Q3,Q4,E1,E2,E3,E4]);
(%o13) [[C=((C2*C3+C1*C2)*C4)/((C3+C2+C1)*C4+C2*C3+C1*C2),Q=(C4*(C2*C3*E+C1*C2*E))/((C3+C2+C1)*C4+C2*C3+C1*C2),Q1=(C1*C2*C4*E)/((C3+C2+C1)*C4+C2*C3+C1*C2),
Q2=(C4*(C2*C3*E+C1*C2*E))/((C3+C2+C1)*C4+C2*C3+C1*C2),Q3=(C2*C3*C4*E)/((C3+C2+C1)*C4+C2*C3+C1*C2),Q4=(C4*(C2*C3*E+C1*C2*E))/((C3+C2+C1)*C4+C2*C3+C1*C2),E1=
(C2*C4*E)/((C3+C2+C1)*C4+C2*C3+C1*C2),E2=(C4*(C3*E+C1*E))/((C3+C2+C1)*C4+C2*C3+C1*C2),E3=(C2*C4*E)/((C3+C2+C1)*C4+C2*C3+C1*C2),E4=
(C2*C3*E+C1*C2*E)/((C3+C2+C1)*C4+C2*C3+C1*C2)]]

となる、C1,C2,C3,C4とEにそれぞれ値を割り当てて計算し直すと。


(%i20) C1: 1*10^-6;
(%o20) 1/1000000
(%i21) C2: 2*10^-6;
(%o21) 1/500000
(%i22) C3: 3*10^-6;
(%o22) 3/1000000
(%i23) C4: 4*10^-6;
(%o23) 1/250000
(%i24) E: 100;
(%o24) 100
(%i25) solve([e1,e2,e3,e4,e5,e6,e7,e8,e9,e10],[C,Q,Q1,Q2,Q3,Q4,E1,E2,E3,E4]);
(%o25) [[C=1/1000000,Q=1/10000,Q1=1/40000,Q2=1/10000,Q3=3/40000,Q4=1/10000,E1=25,E2=50,E3=25,
E4=25]]

となり実数表現に直すと。

(%i27) float(%);
(%o27) floag([[C=9.9999999999999995*10^-7,Q=1.0*10^-4,Q1=2.5000000000000001*10^-5,Q2=1.0*
10^-4,Q3=7.4999999999999993*10^-5,Q4=1.0*10^-4,E1=25.0,E2=50.0,E3=25.0,E4=25.0]])

となり著者の解と同じ結果が得られているのがわかる。

今度はコンデンサをY接続した回路



これも方程式を立てて解くだけ。

(%i25) e1;
(%o25) E1=Q1/C1+E
(%i26) e2;
(%o26) E2=Q3/C3+E
(%i27) e3;
(%o27) E=Q2/C2
(%i28) e4;
(%o28) -Q3+Q2-Q1=0

が図で成り立つのでQ1,Q2,Q3,Eを解くと。

(%i29) solve([e1,e2,e3,e4],[Q1,Q2,Q3,E]);
(%o29) [[Q1=(C1*(C3+C2)*E1-C1*C3*E2)/(C3+C2+C1),Q2=(C2*C3*E2+C1*C2*E1)/(C3+C2+C1),Q3=-(-C2*C3*E2-C1*C3*E2+C1*C3*E1)/(C3+C2+C1),E=
(C3*E2+C1*E1)/(C3+C2+C1)]]

さっくりと著者と同じ解答が得られた。

連立方程式さえ間違いなく立てられればそれを解くにはMaximaにまかせれば良い。

著者の解答では数学公式集に必ず載っている連立方程式の一般解法である行列式を使って解いているが、ITが一般化した時代ではいささか時代遅れの感がある。こういうのは本当に数式処理システムは得意である。人間が苦手なことに労力を煩わす必要は無い。知っておいて損は無いけど、技量をいつまでも保つのは容易ではない。

連立方程式を回路から立てることができるようになれば回路解析は半分終わったも同然。あとは解くだけ。人間の手でやれば詰まらぬ間違いやミスで正しい解が得られない可能性が大である。

回路シミュレーターもとどのつまり連立微分方程式を解いているようなものなので、回路シミュレーターを使って良いという時代に数式処理システムを使って連立方程式を解いても罪にはなるまい。最初は自分で解いてみる努力は必要だと思うけど。